Merge branch 'dev' into restful-api

src/git/cli.v

@@ -0,0 +1,83 @@
+module git
+
+import cli
+import env
+import net.http
+
+struct Config {
+	address string [required]
+	api_key string [required]
+}
+
+// cmd returns the cli submodule that handles the repos API interaction
+pub fn cmd() cli.Command {
+	return cli.Command{
+		name: 'repos'
+		description: 'Interact with the repos API.'
+		commands: [
+			cli.Command{
+				name: 'list'
+				description: 'List the current repos.'
+				execute: fn (cmd cli.Command) ? {
+					config_file := cmd.flags.get_string('config-file') ?
+					conf := env.load<Config>(config_file) ?
+
+					list(conf) ?
+				}
+			},
+			cli.Command{
+				name: 'add'
+				required_args: 2
+				usage: 'url branch'
+				description: 'Add a new repository.'
+				execute: fn (cmd cli.Command) ? {
+					config_file := cmd.flags.get_string('config-file') ?
+					conf := env.load<Config>(config_file) ?
+
+					add(conf, cmd.args[0], cmd.args[1]) ?
+				}
+			},
+			cli.Command{
+				name: 'remove'
+				required_args: 2
+				usage: 'url branch'
+				description: 'Remove a repository.'
+				execute: fn (cmd cli.Command) ? {
+					config_file := cmd.flags.get_string('config-file') ?
+					conf := env.load<Config>(config_file) ?
+
+					remove(conf, cmd.args[0], cmd.args[1]) ?
+				}
+			},
+		]
+	}
+}
+
+fn list(conf Config) ? {
+	mut req := http.new_request(http.Method.get, '$conf.address/api/repos', '') ?
+	req.add_custom_header('X-API-Key', conf.api_key) ?
+
+	res := req.do() ?
+
+	println(res.text)
+}
+
+fn add(conf Config, url string, branch string) ? {
+	mut req := http.new_request(http.Method.post, '$conf.address/api/repos?url=$url&branch=$branch',
+		'') ?
+	req.add_custom_header('X-API-Key', conf.api_key) ?
+
+	res := req.do() ?
+
+	println(res.text)
+}
+
+fn remove(conf Config, url string, branch string) ? {
+	mut req := http.new_request(http.Method.delete, '$conf.address/api/repos?url=$url&branch=$branch',
+		'') ?
+	req.add_custom_header('X-API-Key', conf.api_key) ?
+
+	res := req.do() ?
+
+	println(res.text)
+}

src/git/git.v

@@ -0,0 +1,74 @@
+module git
+
+import os
+import json
+
+pub struct GitRepo {
+pub mut:
+	// URL of the Git repository
+	url string
+	// Branch of the Git repository to use
+	branch string
+	// On which architectures the package is allowed to be built. In reality,
+	// this controls which builders will periodically build the image.
+	arch []string
+}
+
+pub fn (mut r GitRepo) patch_from_params(params map[string]string) {
+	$for field in GitRepo.fields {
+		if field.name in params {
+			$if field.typ is string {
+				r.$(field.name) = params[field.name]
+				// This specific type check is needed for the compiler to ensure
+				// our types are correct
+			} $else $if field.typ is []string {
+				r.$(field.name) = params[field.name].split(',')
+			}
+		}
+	}
+}
+
+pub fn read_repos(path string) ?map[string]GitRepo {
+	if !os.exists(path) {
+		mut f := os.create(path) ?
+
+		defer {
+			f.close()
+		}
+
+		f.write_string('{}') ?
+
+		return {}
+	}
+
+	content := os.read_file(path) ?
+	res := json.decode(map[string]GitRepo, content) ?
+
+	return res
+}
+
+pub fn write_repos(path string, repos &map[string]GitRepo) ? {
+	mut f := os.create(path) ?
+
+	defer {
+		f.close()
+	}
+
+	value := json.encode(repos)
+	f.write_string(value) ?
+}
+
+pub fn repo_from_params(params map[string]string) ?GitRepo {
+	mut repo := GitRepo{}
+
+	// If we're creating a new GitRepo, we want all fields to be present before
+	// "patching".
+	$for field in GitRepo.fields {
+		if field.name !in params {
+			return error('Missing parameter: ${field.name}.')
+		}
+	}
+	repo.patch_from_params(params)
+
+	return repo
+}