# Maintainer: Jef Roosens

_pkgname='alex'
# mc extension to not conflict directly with extra/alex package
pkgname='alex-mc'
pkgver=0.4.1
pkgdesc='Wrapper around Minecraft server processes, designed to complement Docker image installations.'
pkgrel=1
arch=('x86_64' 'aarch64')

url='https://git.rustybever.be/Chewing_Bever/alex'
license=('MIT')

makedepends=('cargo')
depends=('glibc' 'gcc-libs' )

source=("${pkgname}-${pkgver}.tar.gz::https://git.rustybever.be/Chewing_Bever/alex/archive/${pkgver}.tar.gz")
sha512sums=('d157bbbd4c7910d192afe68d8edf56e864337c40e27fa3a2a9af2ce757284c0d0ba3efed78dd12948de3873b2a49451610fbcf50f5097976b56584518351e214')

conflicts=(alex)

prepare() {
    cd "${_pkgname}"

    export RUSTUP_TOOLCHAIN=stable
    cargo fetch --locked --target "${CARCH}-unknown-linux-gnu"
}

build() {
    cd "${_pkgname}"

    export RUSTUP_TOOLCHAIN=stable
    export CARGO_TARGET_DIR=target
    cargo build --frozen --release --all-features
}

check() {
    cd "${_pkgname}"

    export RUSTUP_TOOLCHAIN=stable
    cargo test --frozen --all-features
}

package() {
    install -Dm0755 -t "${pkgdir}/usr/bin/" "${_pkgname}/target/release/${_pkgname}"
}