# Maintainer: Jef Roosens

_pkgname='alex'
# mc extension to not conflict directly with extra/alex package
pkgname='alex-mc'
pkgver=0.3.1
pkgdesc='Wrapper around Minecraft server processes, designed to complement Docker image installations.'
pkgrel=1
arch=('x86_64' 'aarch64')

url='https://git.rustybever.be/Chewing_Bever/alex'
license=('MIT')

makedepends=('cargo')
depends=('glibc' 'gcc-libs' )

source=("${pkgname}-${pkgver}.tar.gz::https://git.rustybever.be/Chewing_Bever/alex/archive/${pkgver}.tar.gz")
sha512sums=('f88903bd99397f3e9a1c4a40febc65eace0d594cde8de20d54ed1cd0597512152111e7a20acaaa971309d5afe1ea267c7ef3b08f0d803237e8004808a83752c5')

conflicts=(alex)

prepare() {
    cd "${_pkgname}"

    export RUSTUP_TOOLCHAIN=stable
    cargo fetch --locked --target "${CARCH}-unknown-linux-gnu"
}

build() {
    cd "${_pkgname}"

    export RUSTUP_TOOLCHAIN=stable
    export CARGO_TARGET_DIR=target
    cargo build --frozen --release --all-features
}

check() {
    cd "${_pkgname}"

    export RUSTUP_TOOLCHAIN=stable
    cargo test --frozen --all-features
}

package() {
    install -Dm0755 -t "${pkgdir}/usr/bin/" "${_pkgname}/target/release/${_pkgname}"
}