jjr-nheko/PKGBUILD

# Maintainer: Konstantinos Sideris <siderisk at auth dot gr>
# Maintainer: Joseph Donofry <joe at joedonofry dot com>

pkgname=jjr-nheko
pkgver=0.9.3.r66.g7138c7a4
pkgrel=1
pkgdesc="Desktop client for the Matrix protocol"
arch=("i686" "x86_64" "aarch64")

url="https://github.com/Nheko-Reborn/nheko"
license=("GPL3")

depends=("qt5-base" "lmdb" "qt5-graphicaleffects" "qt5-multimedia" "qt5-svg" "qt5-quickcontrols2" "qt5-declarative" "qtkeychain-qt5" "cmark" "openssl" "hicolor-icon-theme" "gstreamer" "gst-plugins-base" "gst-plugins-good" "gst-plugins-bad" "gst-plugin-qmlgl" "libnice" "libolm" "spdlog" "curl" "libevent" "qt5-imageformats")
makedepends=("git" "cmake" "gcc" "fontconfig" "qt5-tools" "nlohmann-json" "asciidoc" "sccache")
optdepends=("qt-jdenticon")
provides=("nheko")
conflicts=("nheko" "nheko-git")

source=($pkgname::git+https://github.com/Nheko-Reborn/nheko.git#branch=master)
md5sums=("SKIP")

pkgver() {
    cd "$pkgname"
    git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
    rm -f "$pkgname"/cmake/FindOlm.cmake

    cmake -B build -S "$pkgname" -Wno-dev \
        -DCMAKE_INSTALL_PREFIX=/usr \
        -DHUNTER_ENABLED=OFF \
        -DBUILD_SHARED_LIBS=OFF \
        -DUSE_BUNDLED_MTXCLIENT=ON \
        -DUSE_BUNDLED_COEURL=ON \
        -DUSE_BUNDLED_LMDBXX=ON \
        -DCMAKE_BUILD_TYPE=Release \
        -DCMAKE_C_COMPILER_LAUNCHER=sccache \
        -DCMAKE_CXX_COMPILER_LAUNCHER=sccache
    SCCACHE_S3_KEY_PREFIX="$pkgname" cmake --build build --config Release
}

package() {
    DESTDIR="$pkgdir" cmake --install build
}