packwiz-git/PKGBUILD

# Maintainer: Jef Roosens

pkgbase='packwiz-git'
pkgname='packwiz-git'
pkgver=r211.e71b63e
pkgrel=1
pkgdesc='packwiz is a command line tool for creating Minecraft modpacks.'
arch=('x86_64')

url='https://github.com/packwiz/packwiz'
license=('MIT')

depends=('glibc')
makedepends=('git' 'go')

source=("${pkgname}::git+https://github.com/packwiz/packwiz#branch=master")
md5sums=('SKIP')

pkgver() {
    cd "${pkgname}"

    commit_count="$(git rev-list --count HEAD)"
    commit="$(git rev-parse --short HEAD)"

    echo "r${commit_count}.${commit}"
}

build() {
    cd "${pkgname}"

    go build -ldflags '-s -w'
}

package() {
    cd "${pkgname}"

    install -Dm755 'packwiz' "${pkgdir}/usr/bin/packwiz"

    ./packwiz completion bash | install -Dm644 '/dev/stdin' "${pkgdir}/usr/share/bash-completion/completions/packwiz"
    ./packwiz completion zsh | install -Dm644 '/dev/stdin' "${pkgdir}/usr/share/zsh/site-functions/_packwiz"
    ./packwiz completion fish | install -Dm644 '/dev/stdin' "${pkgdir}/usr/share/fish/vendor_completions.d/packwiz.fish"
}