From 58c1ecd25e82f4466093151525454cf420ecfc6e Mon Sep 17 00:00:00 2001
From: Jef Roosens <roosensjef@gmail.com>
Date: Sat, 7 May 2022 14:16:30 +0200
Subject: [PATCH 01/10] db: added BuildLog & required methods

---
 src/db/db.v   |  1 +
 src/db/git.v  |  2 +-
 src/db/logs.v | 47 +++++++++++++++++++++++++++++++++++++++++++++++
 3 files changed, 49 insertions(+), 1 deletion(-)
 create mode 100644 src/db/logs.v

diff --git a/src/db/db.v b/src/db/db.v
index a75c34c..5ec240d 100644
--- a/src/db/db.v
+++ b/src/db/db.v
@@ -12,6 +12,7 @@ pub fn init(db_path string) ?VieterDb {
 
 	sql conn {
 		create table GitRepo
+		create table BuildLog
 	}
 
 	return VieterDb{
diff --git a/src/db/git.v b/src/db/git.v
index c40086b..b779140 100644
--- a/src/db/git.v
+++ b/src/db/git.v
@@ -94,7 +94,7 @@ pub fn (db &VieterDb) get_git_repo(repo_id int) ?GitRepo {
 	// If a select statement fails, it returns a zeroed object. By
 	// checking one of the required fields, we can see whether the query
 	// returned a result or not.
-	if res.url == '' {
+	if res.id == 0 {
 		return none
 	}
 
diff --git a/src/db/logs.v b/src/db/logs.v
new file mode 100644
index 0000000..3e5b600
--- /dev/null
+++ b/src/db/logs.v
@@ -0,0 +1,47 @@
+module db
+
+import time
+
+pub struct BuildLog {
+	id         int       [primary; sql: serial]
+	repo       GitRepo   [nonull]
+	start_time time.Time [nonull]
+	end_time   time.Time [nonull]
+	exit_code  int       [nonull]
+}
+
+// get_build_logs returns all BuildLog's in the database.
+pub fn (db &VieterDb) get_build_logs() []BuildLog {
+	res := sql db.conn {
+		select from BuildLog order by id
+	}
+
+	return res
+}
+
+// get_build_log tries to return a specific BuildLog.
+pub fn (db &VieterDb) get_build_log(id int) ?BuildLog {
+	res := sql db.conn {
+		select from BuildLog where id == id
+	}
+
+	if res.id == 0 {
+		return none
+	}
+
+	return res
+}
+
+// add_build_log inserts the given BuildLog into the database.
+pub fn (db &VieterDb) add_build_log(log BuildLog) {
+	sql db.conn {
+		insert log into BuildLog
+	}
+}
+
+// delete_build_log delete the BuildLog with the given ID from the database.
+pub fn (db &VieterDb) delete_build_log(id int) {
+	sql db.conn {
+		delete from BuildLog where id == id
+	}
+}
-- 
2.40.1


From 7e01dbafec2ecb6dd92debc79a2b9f0f107d7198 Mon Sep 17 00:00:00 2001
From: Jef Roosens <roosensjef@gmail.com>
Date: Sat, 7 May 2022 15:10:07 +0200
Subject: [PATCH 02/10] feat(server): added endpoints for listing & uploading
 build logs

---
 src/server/logs.v   | 99 +++++++++++++++++++++++++++++++++++++++++++++
 src/server/server.v |  9 +++++
 2 files changed, 108 insertions(+)
 create mode 100644 src/server/logs.v

diff --git a/src/server/logs.v b/src/server/logs.v
new file mode 100644
index 0000000..01116b4
--- /dev/null
+++ b/src/server/logs.v
@@ -0,0 +1,99 @@
+module server
+
+import web
+import net.http
+import net.urllib
+import response { new_data_response, new_response }
+import db
+import time
+import os
+import util
+
+['/api/logs'; get]
+fn (mut app App) get_logs() web.Result {
+	if !app.is_authorized() {
+		return app.json(http.Status.unauthorized, new_response('Unauthorized.'))
+	}
+
+	logs := app.db.get_build_logs()
+
+	return app.json(http.Status.ok, new_data_response(logs))
+}
+
+// parse_query_time unescapes an HTTP query parameter & tries to parse it as a
+// time.Time struct.
+fn parse_query_time(query string) ?time.Time {
+	unescaped := urllib.query_unescape(query) ?
+	t := time.parse(unescaped) ?
+
+	return t
+}
+
+['/api/logs'; post]
+fn (mut app App) post_log() web.Result {
+	if !app.is_authorized() {
+		return app.json(http.Status.unauthorized, new_response('Unauthorized.'))
+	}
+
+	// Parse query params
+	start_time := parse_query_time(app.query['startTime']) or {
+		return app.json(http.Status.bad_request, new_response('Invalid or missing start time.'))
+	}
+
+	end_time := time.parse(app.query['endTime'].replace('_', ' ')) or {
+		return app.json(http.Status.bad_request, new_response('Invalid or missing end time.'))
+	}
+
+	if 'exitCode' !in app.query {
+		return app.json(http.Status.bad_request, new_response('Missing exit code.'))
+	}
+
+	exit_code := app.query['exitCode'].int()
+
+	if 'arch' !in app.query {
+		return app.json(http.Status.bad_request, new_response("Missing parameter 'arch'."))
+	}
+
+	arch := app.query['arch']
+
+	repo := app.db.get_git_repo(app.query['repo'].int()) or {
+		return app.json(http.Status.bad_request, new_response('Unknown repo.'))
+	}
+
+	// Store log in db
+	log := db.BuildLog{
+		repo: repo
+		start_time: start_time
+		end_time: end_time
+		exit_code: exit_code
+	}
+
+	app.db.add_build_log(log)
+
+	repo_logs_dir := os.join_path(app.conf.data_dir, logs_dir_name, repo.id.str(), arch)
+
+	// Create the logs directory of it doesn't exist
+	if !os.exists(repo_logs_dir) {
+		os.mkdir_all(repo_logs_dir) or {
+			app.lerror("Couldn't create dir '$repo_logs_dir'.")
+
+			return app.json(http.Status.internal_server_error, new_response('An error occured while processing the request.'))
+		}
+	}
+
+	// Stream log contents to correct file
+	file_name := start_time.custom_format('YYYY-MM-DD_HH-mm-ss')
+	full_path := os.join_path_single(repo_logs_dir, file_name)
+
+	if length := app.req.header.get(.content_length) {
+		util.reader_to_file(mut app.reader, length.int(), full_path) or {
+			app.lerror('An error occured while receiving logs: $err.msg()')
+
+			return app.json(http.Status.internal_server_error, new_response('Failed to upload logs.'))
+		}
+	} else {
+		return app.status(http.Status.length_required)
+	}
+
+	return app.json(http.Status.ok, new_response('Logs added successfully.'))
+}
diff --git a/src/server/server.v b/src/server/server.v
index b2a2ad2..090aa76 100644
--- a/src/server/server.v
+++ b/src/server/server.v
@@ -12,6 +12,7 @@ const (
 	log_file_name = 'vieter.log'
 	repo_dir_name = 'repos'
 	db_file_name  = 'vieter.sqlite'
+	logs_dir_name = 'logs'
 )
 
 struct App {
@@ -37,6 +38,14 @@ pub fn server(conf Config) ? {
 
 	os.mkdir_all(conf.data_dir) or { util.exit_with_message(1, 'Failed to create data directory.') }
 
+	logs_dir := os.join_path_single(conf.data_dir, server.logs_dir_name)
+
+	if !os.exists(logs_dir) {
+		os.mkdir(os.join_path_single(conf.data_dir, server.logs_dir_name)) or {
+			util.exit_with_message(1, 'Failed to create logs directory.')
+		}
+	}
+
 	mut logger := log.Log{
 		level: log_level
 	}
-- 
2.40.1


From 393e641a7666682c1e4ff38b83affbf596c461d6 Mon Sep 17 00:00:00 2001
From: Jef Roosens <roosensjef@gmail.com>
Date: Sat, 7 May 2022 15:31:01 +0200
Subject: [PATCH 03/10] feat(server): allow filtering of builds per repo

---
 src/db/logs.v     | 12 +++++++++++-
 src/server/logs.v | 16 +++++++++++-----
 2 files changed, 22 insertions(+), 6 deletions(-)

diff --git a/src/db/logs.v b/src/db/logs.v
index 3e5b600..9a2405b 100644
--- a/src/db/logs.v
+++ b/src/db/logs.v
@@ -4,7 +4,7 @@ import time
 
 pub struct BuildLog {
 	id         int       [primary; sql: serial]
-	repo       GitRepo   [nonull]
+	repo_id    int       [nonull]
 	start_time time.Time [nonull]
 	end_time   time.Time [nonull]
 	exit_code  int       [nonull]
@@ -19,6 +19,16 @@ pub fn (db &VieterDb) get_build_logs() []BuildLog {
 	return res
 }
 
+// get_build_logs_for_repo returns all BuildLog's in the database for a given
+// repo.
+pub fn (db &VieterDb) get_build_logs_for_repo(repo_id int) []BuildLog {
+	res := sql db.conn {
+		select from BuildLog where repo_id == repo_id order by id
+	}
+
+	return res
+}
+
 // get_build_log tries to return a specific BuildLog.
 pub fn (db &VieterDb) get_build_log(id int) ?BuildLog {
 	res := sql db.conn {
diff --git a/src/server/logs.v b/src/server/logs.v
index 01116b4..8b0f297 100644
--- a/src/server/logs.v
+++ b/src/server/logs.v
@@ -15,7 +15,11 @@ fn (mut app App) get_logs() web.Result {
 		return app.json(http.Status.unauthorized, new_response('Unauthorized.'))
 	}
 
-	logs := app.db.get_build_logs()
+	logs := if 'repo' in app.query {
+		app.db.get_build_logs_for_repo(app.query['repo'].int())
+	} else {
+		app.db.get_build_logs()
+	}
 
 	return app.json(http.Status.ok, new_data_response(logs))
 }
@@ -56,13 +60,15 @@ fn (mut app App) post_log() web.Result {
 
 	arch := app.query['arch']
 
-	repo := app.db.get_git_repo(app.query['repo'].int()) or {
-		return app.json(http.Status.bad_request, new_response('Unknown repo.'))
+	repo := app.query['repo'].int()
+
+	if repo == 0 {
+		return app.json(http.Status.bad_request, new_response('Invalid Git repo.'))
 	}
 
 	// Store log in db
 	log := db.BuildLog{
-		repo: repo
+		repo_id: repo
 		start_time: start_time
 		end_time: end_time
 		exit_code: exit_code
@@ -70,7 +76,7 @@ fn (mut app App) post_log() web.Result {
 
 	app.db.add_build_log(log)
 
-	repo_logs_dir := os.join_path(app.conf.data_dir, logs_dir_name, repo.id.str(), arch)
+	repo_logs_dir := os.join_path(app.conf.data_dir, logs_dir_name, repo.str(), arch)
 
 	// Create the logs directory of it doesn't exist
 	if !os.exists(repo_logs_dir) {
-- 
2.40.1


From 139142fcec4f66ad08e95ed4dcf6c3c30acc423e Mon Sep 17 00:00:00 2001
From: Jef Roosens <roosensjef@gmail.com>
Date: Sat, 7 May 2022 15:41:49 +0200
Subject: [PATCH 04/10] feat(server): added endpoint for content of build log

---
 src/db/logs.v     |  2 ++
 src/server/logs.v | 27 ++++++++++++++++++++++++++-
 2 files changed, 28 insertions(+), 1 deletion(-)

diff --git a/src/db/logs.v b/src/db/logs.v
index 9a2405b..589304e 100644
--- a/src/db/logs.v
+++ b/src/db/logs.v
@@ -3,10 +3,12 @@ module db
 import time
 
 pub struct BuildLog {
+pub:
 	id         int       [primary; sql: serial]
 	repo_id    int       [nonull]
 	start_time time.Time [nonull]
 	end_time   time.Time [nonull]
+	arch string [nonull]
 	exit_code  int       [nonull]
 }
 
diff --git a/src/server/logs.v b/src/server/logs.v
index 8b0f297..9bddc21 100644
--- a/src/server/logs.v
+++ b/src/server/logs.v
@@ -24,6 +24,30 @@ fn (mut app App) get_logs() web.Result {
 	return app.json(http.Status.ok, new_data_response(logs))
 }
 
+['/api/logs/:id'; get]
+fn (mut app App) get_single_log(id int) web.Result {
+	if !app.is_authorized() {
+		return app.json(http.Status.unauthorized, new_response('Unauthorized.'))
+	}
+	
+	log := app.db.get_build_log(id) or { return app.not_found() }
+
+	return app.json(http.Status.ok, new_data_response(log))
+}
+
+['/api/logs/:id/content'; get]
+fn (mut app App) get_log_contents(id int) web.Result {
+	if !app.is_authorized() {
+		return app.json(http.Status.unauthorized, new_response('Unauthorized.'))
+	}
+
+	log := app.db.get_build_log(id) or { return app.not_found() }
+	file_name := log.start_time.custom_format('YYYY-MM-DD_HH-mm-ss')
+	full_path := os.join_path(app.conf.data_dir, server.logs_dir_name, log.repo_id.str(), log.arch, file_name)
+
+	return app.file(full_path)
+}
+
 // parse_query_time unescapes an HTTP query parameter & tries to parse it as a
 // time.Time struct.
 fn parse_query_time(query string) ?time.Time {
@@ -44,7 +68,7 @@ fn (mut app App) post_log() web.Result {
 		return app.json(http.Status.bad_request, new_response('Invalid or missing start time.'))
 	}
 
-	end_time := time.parse(app.query['endTime'].replace('_', ' ')) or {
+	end_time := parse_query_time(app.query['endTime']) or {
 		return app.json(http.Status.bad_request, new_response('Invalid or missing end time.'))
 	}
 
@@ -71,6 +95,7 @@ fn (mut app App) post_log() web.Result {
 		repo_id: repo
 		start_time: start_time
 		end_time: end_time
+		arch: arch
 		exit_code: exit_code
 	}
 
-- 
2.40.1


From f42d3fd8b0f2005f96b94e39c66e94f300b2649e Mon Sep 17 00:00:00 2001
From: Jef Roosens <roosensjef@gmail.com>
Date: Sat, 7 May 2022 15:44:59 +0200
Subject: [PATCH 05/10] fix(server): prevent adding logs to non-existent repo

---
 src/db/git.v      |  8 ++++++++
 src/server/logs.v | 10 +++++-----
 2 files changed, 13 insertions(+), 5 deletions(-)

diff --git a/src/db/git.v b/src/db/git.v
index b779140..6eeecc8 100644
--- a/src/db/git.v
+++ b/src/db/git.v
@@ -152,3 +152,11 @@ pub fn (db &VieterDb) update_git_repo_archs(repo_id int, archs []GitRepoArch) {
 		}
 	}
 }
+
+pub fn (db &VieterDb) git_repo_exists(repo_id int) bool {
+	db.get_git_repo(repo_id) or {
+		return false
+	}
+	
+	return true
+}
diff --git a/src/server/logs.v b/src/server/logs.v
index 9bddc21..10b734d 100644
--- a/src/server/logs.v
+++ b/src/server/logs.v
@@ -84,15 +84,15 @@ fn (mut app App) post_log() web.Result {
 
 	arch := app.query['arch']
 
-	repo := app.query['repo'].int()
+	repo_id := app.query['repo'].int()
 
-	if repo == 0 {
-		return app.json(http.Status.bad_request, new_response('Invalid Git repo.'))
+	if !app.db.git_repo_exists(repo_id) {
+		return app.json(http.Status.bad_request, new_response('Unknown Git repo.'))
 	}
 
 	// Store log in db
 	log := db.BuildLog{
-		repo_id: repo
+		repo_id: repo_id
 		start_time: start_time
 		end_time: end_time
 		arch: arch
@@ -101,7 +101,7 @@ fn (mut app App) post_log() web.Result {
 
 	app.db.add_build_log(log)
 
-	repo_logs_dir := os.join_path(app.conf.data_dir, logs_dir_name, repo.str(), arch)
+	repo_logs_dir := os.join_path(app.conf.data_dir, logs_dir_name, repo_id.str(), arch)
 
 	// Create the logs directory of it doesn't exist
 	if !os.exists(repo_logs_dir) {
-- 
2.40.1


From 407b2269556e23d561ecd878c82c898502d28fc5 Mon Sep 17 00:00:00 2001
From: Jef Roosens <roosensjef@gmail.com>
Date: Sat, 7 May 2022 16:10:27 +0200
Subject: [PATCH 06/10] refactor: moved client code into own module

---
 src/build/build.v        |  4 +--
 src/client/client.v      | 40 +++++++++++++++++++++
 src/client/git.v         | 51 ++++++++++++++++++++++++++
 src/cron/daemon/build.v  |  2 +-
 src/cron/daemon/daemon.v | 10 +++---
 src/git/cli.v            | 17 ++++++---
 src/git/client.v         | 77 ----------------------------------------
 7 files changed, 110 insertions(+), 91 deletions(-)
 create mode 100644 src/client/client.v
 create mode 100644 src/client/git.v
 delete mode 100644 src/git/client.v

diff --git a/src/build/build.v b/src/build/build.v
index 15a5eb8..6f033e6 100644
--- a/src/build/build.v
+++ b/src/build/build.v
@@ -3,9 +3,9 @@ module build
 import docker
 import encoding.base64
 import time
-import git
 import os
 import db
+import client
 
 const container_build_dir = '/build'
 
@@ -126,7 +126,7 @@ fn build(conf Config) ? {
 	build_arch := os.uname().machine
 
 	// We get the repos map from the Vieter instance
-	repos := git.get_repos(conf.address, conf.api_key) ?
+	repos := client.new(conf.address, conf.api_key).get_git_repos() ?
 
 	// We filter out any repos that aren't allowed to be built on this
 	// architecture
diff --git a/src/client/client.v b/src/client/client.v
new file mode 100644
index 0000000..614b3db
--- /dev/null
+++ b/src/client/client.v
@@ -0,0 +1,40 @@
+module client
+
+import net.http
+import response { Response }
+import json
+
+pub struct Client {
+pub:
+	address string
+	api_key string
+}
+
+pub fn new(address string, api_key string) Client {
+	return Client{
+		address: address
+		api_key: api_key
+	}
+}
+
+// send_request<T> is a convenience method for sending requests to the repos
+// API. It mostly does string manipulation to create a query string containing
+// the provided params.
+fn (c &Client) send_request<T>(method http.Method, url string, params map[string]string) ?Response<T> {
+	mut full_url := '${c.address}$url'
+
+	if params.len > 0 {
+		params_str := params.keys().map('$it=${params[it]}').join('&')
+
+		full_url = '$full_url?$params_str'
+	}
+
+	mut req := http.new_request(method, full_url, '') ?
+	req.add_custom_header('X-API-Key', c.api_key) ?
+
+	res := req.do() ?
+	data := json.decode(Response<T>, res.text) ?
+
+	return data
+}
+
diff --git a/src/client/git.v b/src/client/git.v
new file mode 100644
index 0000000..5ed0620
--- /dev/null
+++ b/src/client/git.v
@@ -0,0 +1,51 @@
+module client
+
+import db
+import net.http
+import response { Response }
+
+// get_repos returns the current list of repos.
+pub fn (c &Client) get_git_repos() ?[]db.GitRepo {
+	data := c.send_request<[]db.GitRepo>(http.Method.get, '/api/repos', {}) ?
+
+	return data.data
+}
+
+// get_repo returns the repo for a specific ID.
+pub fn (c &Client) get_git_repo(id int) ?db.GitRepo {
+	data := c.send_request<db.GitRepo>(http.Method.get, '/api/repos/$id', {}) ?
+
+	return data.data
+}
+
+// add_repo adds a new repo to the server.
+pub fn (c &Client) add_git_repo(url string, branch string, repo string, arch []string) ?Response<string> {
+	mut params := {
+		'url':    url
+		'branch': branch
+		'repo':   repo
+	}
+
+	if arch.len > 0 {
+		params['arch'] = arch.join(',')
+	}
+
+	data := c.send_request<string>(http.Method.post, '/api/repos', params) ?
+
+	return data
+}
+
+// remove_repo removes the repo with the given ID from the server.
+pub fn (c &Client) remove_git_repo(id int) ?Response<string> {
+	data := c.send_request<string>(http.Method.delete, '/api/repos/$id', {}) ?
+
+	return data
+}
+
+// patch_repo sends a PATCH request to the given repo with the params as
+// payload.
+pub fn (c &Client) patch_git_repo(id int, params map[string]string) ?Response<string> {
+	data := c.send_request<string>(http.Method.patch, '/api/repos/$id', params) ?
+
+	return data
+}
diff --git a/src/cron/daemon/build.v b/src/cron/daemon/build.v
index e54a39e..d107fd3 100644
--- a/src/cron/daemon/build.v
+++ b/src/cron/daemon/build.v
@@ -77,7 +77,7 @@ fn (mut d Daemon) run_build(build_index int, sb ScheduledBuild) {
 	// 0 means success, 1 means failure
 	mut status := 0
 
-	build.build_repo(d.address, d.api_key, d.builder_images.last(), &sb.repo) or {
+	build.build_repo(d.client.address, d.client.api_key, d.builder_images.last(), &sb.repo) or {
 		d.ldebug('build_repo error: $err.msg()')
 		status = 1
 	}
diff --git a/src/cron/daemon/daemon.v b/src/cron/daemon/daemon.v
index ffa2f6e..71fc575 100644
--- a/src/cron/daemon/daemon.v
+++ b/src/cron/daemon/daemon.v
@@ -1,6 +1,5 @@
 module daemon
 
-import git
 import time
 import log
 import datatypes { MinHeap }
@@ -10,6 +9,7 @@ import build
 import docker
 import db
 import os
+import client
 
 const (
 	// How many seconds to wait before retrying to update API if failed
@@ -31,8 +31,7 @@ fn (r1 ScheduledBuild) < (r2 ScheduledBuild) bool {
 
 pub struct Daemon {
 mut:
-	address                 string
-	api_key                 string
+	client client.Client
 	base_image              string
 	builder_images          []string
 	global_schedule         CronExpression
@@ -56,8 +55,7 @@ mut:
 // populates the build queue for the first time.
 pub fn init_daemon(logger log.Log, address string, api_key string, base_image string, global_schedule CronExpression, max_concurrent_builds int, api_update_frequency int, image_rebuild_frequency int) ?Daemon {
 	mut d := Daemon{
-		address: address
-		api_key: api_key
+		client: client.new(address, api_key)
 		base_image: base_image
 		global_schedule: global_schedule
 		api_update_frequency: api_update_frequency
@@ -180,7 +178,7 @@ fn (mut d Daemon) schedule_build(repo db.GitRepo) {
 fn (mut d Daemon) renew_repos() {
 	d.linfo('Renewing repos...')
 
-	mut new_repos := git.get_repos(d.address, d.api_key) or {
+	mut new_repos := d.client.get_git_repos() or {
 		d.lerror('Failed to renew repos. Retrying in ${daemon.api_update_retry_timeout}s...')
 		d.api_update_timestamp = time.now().add_seconds(daemon.api_update_retry_timeout)
 
diff --git a/src/git/cli.v b/src/git/cli.v
index 634b778..bdc0479 100644
--- a/src/git/cli.v
+++ b/src/git/cli.v
@@ -3,6 +3,7 @@ module git
 import cli
 import env
 import cron.expression { parse_expression }
+import client
 
 struct Config {
 	address string [required]
@@ -119,7 +120,8 @@ pub fn cmd() cli.Command {
 
 // list prints out a list of all repositories.
 fn list(conf Config) ? {
-	repos := get_repos(conf.address, conf.api_key) ?
+	c := client.new(conf.address, conf.api_key)
+	repos := c.get_git_repos() ?
 
 	for repo in repos {
 		println('$repo.id\t$repo.url\t$repo.branch\t$repo.repo')
@@ -128,7 +130,8 @@ fn list(conf Config) ? {
 
 // add adds a new repository to the server's list.
 fn add(conf Config, url string, branch string, repo string) ? {
-	res := add_repo(conf.address, conf.api_key, url, branch, repo, []) ?
+	c := client.new(conf.address, conf.api_key)
+	res := c.add_git_repo(url, branch, repo, []) ?
 
 	println(res.message)
 }
@@ -139,7 +142,8 @@ fn remove(conf Config, id string) ? {
 	id_int := id.int()
 
 	if id_int != 0 {
-		res := remove_repo(conf.address, conf.api_key, id_int) ?
+		c := client.new(conf.address, conf.api_key)
+		res := c.remove_git_repo(id_int) ?
 		println(res.message)
 	}
 }
@@ -156,7 +160,9 @@ fn patch(conf Config, id string, params map[string]string) ? {
 
 	id_int := id.int()
 	if id_int != 0 {
-		res := patch_repo(conf.address, conf.api_key, id_int, params) ?
+
+		c := client.new(conf.address, conf.api_key)
+		res := c.patch_git_repo(id_int, params) ?
 
 		println(res.message)
 	}
@@ -170,6 +176,7 @@ fn info(conf Config, id string) ? {
 		return
 	}
 
-	repo := get_repo(conf.address, conf.api_key, id_int) ?
+		c := client.new(conf.address, conf.api_key)
+	repo := c.get_git_repo(id_int) ?
 	println(repo)
 }
diff --git a/src/git/client.v b/src/git/client.v
deleted file mode 100644
index b5f8e9f..0000000
--- a/src/git/client.v
+++ /dev/null
@@ -1,77 +0,0 @@
-module git
-
-import json
-import response { Response }
-import net.http
-import db
-
-// send_request<T> is a convenience method for sending requests to the repos
-// API. It mostly does string manipulation to create a query string containing
-// the provided params.
-fn send_request<T>(method http.Method, address string, url string, api_key string, params map[string]string) ?Response<T> {
-	mut full_url := '$address$url'
-
-	if params.len > 0 {
-		params_str := params.keys().map('$it=${params[it]}').join('&')
-
-		full_url = '$full_url?$params_str'
-	}
-
-	mut req := http.new_request(method, full_url, '') ?
-	req.add_custom_header('X-API-Key', api_key) ?
-
-	res := req.do() ?
-	data := json.decode(Response<T>, res.text) ?
-
-	return data
-}
-
-// get_repos returns the current list of repos.
-pub fn get_repos(address string, api_key string) ?[]db.GitRepo {
-	data := send_request<[]db.GitRepo>(http.Method.get, address, '/api/repos', api_key,
-		{}) ?
-
-	return data.data
-}
-
-// get_repo returns the repo for a specific ID.
-pub fn get_repo(address string, api_key string, id int) ?db.GitRepo {
-	data := send_request<db.GitRepo>(http.Method.get, address, '/api/repos/$id', api_key,
-		{}) ?
-
-	return data.data
-}
-
-// add_repo adds a new repo to the server.
-pub fn add_repo(address string, api_key string, url string, branch string, repo string, arch []string) ?Response<string> {
-	mut params := {
-		'url':    url
-		'branch': branch
-		'repo':   repo
-	}
-
-	if arch.len > 0 {
-		params['arch'] = arch.join(',')
-	}
-
-	data := send_request<string>(http.Method.post, address, '/api/repos', api_key, params) ?
-
-	return data
-}
-
-// remove_repo removes the repo with the given ID from the server.
-pub fn remove_repo(address string, api_key string, id int) ?Response<string> {
-	data := send_request<string>(http.Method.delete, address, '/api/repos/$id', api_key,
-		{}) ?
-
-	return data
-}
-
-// patch_repo sends a PATCH request to the given repo with the params as
-// payload.
-pub fn patch_repo(address string, api_key string, id int, params map[string]string) ?Response<string> {
-	data := send_request<string>(http.Method.patch, address, '/api/repos/$id', api_key,
-		params) ?
-
-	return data
-}
-- 
2.40.1


From fa6603bd459c1f3c240d5f389e33441488cebcbf Mon Sep 17 00:00:00 2001
From: Jef Roosens <roosensjef@gmail.com>
Date: Sat, 7 May 2022 19:38:28 +0200
Subject: [PATCH 07/10] feat(client): added client code for logs API

---
 src/client/client.v      | 32 ++++++++++++++++++++----------
 src/client/git.v         | 18 ++++++++---------
 src/client/logs.v        | 42 ++++++++++++++++++++++++++++++++++++++++
 src/cron/daemon/daemon.v |  2 +-
 src/db/git.v             |  6 ++----
 src/db/logs.v            |  2 +-
 src/git/cli.v            |  3 +--
 src/server/logs.v        |  5 +++--
 8 files changed, 81 insertions(+), 29 deletions(-)
 create mode 100644 src/client/logs.v

diff --git a/src/client/client.v b/src/client/client.v
index 614b3db..7446e91 100644
--- a/src/client/client.v
+++ b/src/client/client.v
@@ -1,6 +1,7 @@
 module client
 
-import net.http
+import net.http { Method }
+import net.urllib
 import response { Response }
 import json
 
@@ -17,24 +18,35 @@ pub fn new(address string, api_key string) Client {
 	}
 }
 
-// send_request<T> is a convenience method for sending requests to the repos
-// API. It mostly does string manipulation to create a query string containing
-// the provided params.
-fn (c &Client) send_request<T>(method http.Method, url string, params map[string]string) ?Response<T> {
-	mut full_url := '${c.address}$url'
+// send_request<T> just calls send_request_with_body<T> with an empty body.
+fn (c &Client) send_request<T>(method Method, url string, params map[string]string) ?Response<T> {
+	return c.send_request_with_body<T>(method, url, params, '')
+}
+
+// send_request_with_body<T> is a convenience method for sending requests to
+// the repos API. It mostly does string manipulation to create a query string
+// containing the provided params.
+fn (c &Client) send_request_with_body<T>(method Method, url string, params map[string]string, body string) ?Response<T> {
+	mut full_url := '$c.address$url'
 
 	if params.len > 0 {
-		params_str := params.keys().map('$it=${params[it]}').join('&')
+		mut params_escaped := map[string]string{}
+
+		// Escape each query param
+		for k, v in params {
+			params_escaped[k] = urllib.query_escape(v)
+		}
+
+		params_str := params_escaped.keys().map('$it=${params[it]}').join('&')
 
 		full_url = '$full_url?$params_str'
 	}
 
-	mut req := http.new_request(method, full_url, '') ?
-	req.add_custom_header('X-API-Key', c.api_key) ?
+	mut req := http.new_request(method, full_url, body) ?
+	req.add_custom_header('X-Api-Key', c.api_key) ?
 
 	res := req.do() ?
 	data := json.decode(Response<T>, res.text) ?
 
 	return data
 }
-
diff --git a/src/client/git.v b/src/client/git.v
index 5ed0620..7f4c27a 100644
--- a/src/client/git.v
+++ b/src/client/git.v
@@ -1,19 +1,19 @@
 module client
 
-import db
-import net.http
+import db { GitRepo }
+import net.http { Method }
 import response { Response }
 
 // get_repos returns the current list of repos.
-pub fn (c &Client) get_git_repos() ?[]db.GitRepo {
-	data := c.send_request<[]db.GitRepo>(http.Method.get, '/api/repos', {}) ?
+pub fn (c &Client) get_git_repos() ?[]GitRepo {
+	data := c.send_request<[]GitRepo>(Method.get, '/api/repos', {}) ?
 
 	return data.data
 }
 
 // get_repo returns the repo for a specific ID.
-pub fn (c &Client) get_git_repo(id int) ?db.GitRepo {
-	data := c.send_request<db.GitRepo>(http.Method.get, '/api/repos/$id', {}) ?
+pub fn (c &Client) get_git_repo(id int) ?GitRepo {
+	data := c.send_request<GitRepo>(Method.get, '/api/repos/$id', {}) ?
 
 	return data.data
 }
@@ -30,14 +30,14 @@ pub fn (c &Client) add_git_repo(url string, branch string, repo string, arch []s
 		params['arch'] = arch.join(',')
 	}
 
-	data := c.send_request<string>(http.Method.post, '/api/repos', params) ?
+	data := c.send_request<string>(Method.post, '/api/repos', params) ?
 
 	return data
 }
 
 // remove_repo removes the repo with the given ID from the server.
 pub fn (c &Client) remove_git_repo(id int) ?Response<string> {
-	data := c.send_request<string>(http.Method.delete, '/api/repos/$id', {}) ?
+	data := c.send_request<string>(Method.delete, '/api/repos/$id', {}) ?
 
 	return data
 }
@@ -45,7 +45,7 @@ pub fn (c &Client) remove_git_repo(id int) ?Response<string> {
 // patch_repo sends a PATCH request to the given repo with the params as
 // payload.
 pub fn (c &Client) patch_git_repo(id int, params map[string]string) ?Response<string> {
-	data := c.send_request<string>(http.Method.patch, '/api/repos/$id', params) ?
+	data := c.send_request<string>(Method.patch, '/api/repos/$id', params) ?
 
 	return data
 }
diff --git a/src/client/logs.v b/src/client/logs.v
new file mode 100644
index 0000000..9182f69
--- /dev/null
+++ b/src/client/logs.v
@@ -0,0 +1,42 @@
+module client
+
+import db { BuildLog }
+import net.http { Method }
+import response { Response }
+import time
+
+pub fn (c &Client) get_build_logs() ?Response<[]BuildLog> {
+	data := c.send_request<[]BuildLog>(Method.get, '/api/logs', {}) ?
+
+	return data
+}
+
+pub fn (c &Client) get_build_logs_for_repo(repo_id int) ?Response<[]BuildLog> {
+	params := {
+		'repo': repo_id.str()
+	}
+
+	data := c.send_request<[]BuildLog>(Method.get, '/api/logs', params) ?
+
+	return data
+}
+
+pub fn (c &Client) get_build_log(id int) ?Response<BuildLog> {
+	data := c.send_request<BuildLog>(Method.get, '/api/logs/$id', {}) ?
+
+	return data
+}
+
+pub fn (c &Client) add_build_log(repo_id int, start_time time.Time, end_time time.Time, arch string, exit_code int, content string) ?Response<string> {
+	params := {
+		'repo':      repo_id.str()
+		'startTime': start_time.str()
+		'endTime':   end_time.str()
+		'arch':      arch
+		'exitCode':  exit_code.str()
+	}
+
+	data := c.send_request_with_body<string>(Method.post, '/api/logs', params, content) ?
+
+	return data
+}
diff --git a/src/cron/daemon/daemon.v b/src/cron/daemon/daemon.v
index 71fc575..ade8fcb 100644
--- a/src/cron/daemon/daemon.v
+++ b/src/cron/daemon/daemon.v
@@ -31,7 +31,7 @@ fn (r1 ScheduledBuild) < (r2 ScheduledBuild) bool {
 
 pub struct Daemon {
 mut:
-	client client.Client
+	client                  client.Client
 	base_image              string
 	builder_images          []string
 	global_schedule         CronExpression
diff --git a/src/db/git.v b/src/db/git.v
index 6eeecc8..7aba284 100644
--- a/src/db/git.v
+++ b/src/db/git.v
@@ -154,9 +154,7 @@ pub fn (db &VieterDb) update_git_repo_archs(repo_id int, archs []GitRepoArch) {
 }
 
 pub fn (db &VieterDb) git_repo_exists(repo_id int) bool {
-	db.get_git_repo(repo_id) or {
-		return false
-	}
-	
+	db.get_git_repo(repo_id) or { return false }
+
 	return true
 }
diff --git a/src/db/logs.v b/src/db/logs.v
index 589304e..9ce2865 100644
--- a/src/db/logs.v
+++ b/src/db/logs.v
@@ -8,7 +8,7 @@ pub:
 	repo_id    int       [nonull]
 	start_time time.Time [nonull]
 	end_time   time.Time [nonull]
-	arch string [nonull]
+	arch       string    [nonull]
 	exit_code  int       [nonull]
 }
 
diff --git a/src/git/cli.v b/src/git/cli.v
index bdc0479..3bf78d1 100644
--- a/src/git/cli.v
+++ b/src/git/cli.v
@@ -160,7 +160,6 @@ fn patch(conf Config, id string, params map[string]string) ? {
 
 	id_int := id.int()
 	if id_int != 0 {
-
 		c := client.new(conf.address, conf.api_key)
 		res := c.patch_git_repo(id_int, params) ?
 
@@ -176,7 +175,7 @@ fn info(conf Config, id string) ? {
 		return
 	}
 
-		c := client.new(conf.address, conf.api_key)
+	c := client.new(conf.address, conf.api_key)
 	repo := c.get_git_repo(id_int) ?
 	println(repo)
 }
diff --git a/src/server/logs.v b/src/server/logs.v
index 10b734d..f53464d 100644
--- a/src/server/logs.v
+++ b/src/server/logs.v
@@ -29,7 +29,7 @@ fn (mut app App) get_single_log(id int) web.Result {
 	if !app.is_authorized() {
 		return app.json(http.Status.unauthorized, new_response('Unauthorized.'))
 	}
-	
+
 	log := app.db.get_build_log(id) or { return app.not_found() }
 
 	return app.json(http.Status.ok, new_data_response(log))
@@ -43,7 +43,8 @@ fn (mut app App) get_log_contents(id int) web.Result {
 
 	log := app.db.get_build_log(id) or { return app.not_found() }
 	file_name := log.start_time.custom_format('YYYY-MM-DD_HH-mm-ss')
-	full_path := os.join_path(app.conf.data_dir, server.logs_dir_name, log.repo_id.str(), log.arch, file_name)
+	full_path := os.join_path(app.conf.data_dir, logs_dir_name, log.repo_id.str(), log.arch,
+		file_name)
 
 	return app.file(full_path)
 }
-- 
2.40.1


From 5b016df85ddcef017648039601ff08668d329ba8 Mon Sep 17 00:00:00 2001
From: Jef Roosens <roosensjef@gmail.com>
Date: Sat, 7 May 2022 21:50:20 +0200
Subject: [PATCH 08/10] feat(cli): added commands for interacting with build
 logs

---
 src/client/client.v                  | 32 ++++++---
 src/client/logs.v                    |  6 ++
 src/console/console.v                |  1 +
 src/{git/cli.v => console/git/git.v} |  0
 src/console/logs/logs.v              | 99 ++++++++++++++++++++++++++++
 src/db/logs.v                        | 14 ++++
 src/main.v                           |  4 +-
 7 files changed, 145 insertions(+), 11 deletions(-)
 create mode 100644 src/console/console.v
 rename src/{git/cli.v => console/git/git.v} (100%)
 create mode 100644 src/console/logs/logs.v

diff --git a/src/client/client.v b/src/client/client.v
index 7446e91..12c92d3 100644
--- a/src/client/client.v
+++ b/src/client/client.v
@@ -18,15 +18,7 @@ pub fn new(address string, api_key string) Client {
 	}
 }
 
-// send_request<T> just calls send_request_with_body<T> with an empty body.
-fn (c &Client) send_request<T>(method Method, url string, params map[string]string) ?Response<T> {
-	return c.send_request_with_body<T>(method, url, params, '')
-}
-
-// send_request_with_body<T> is a convenience method for sending requests to
-// the repos API. It mostly does string manipulation to create a query string
-// containing the provided params.
-fn (c &Client) send_request_with_body<T>(method Method, url string, params map[string]string, body string) ?Response<T> {
+fn (c &Client) send_request_raw(method Method, url string, params map[string]string, body string) ?http.Response {
 	mut full_url := '$c.address$url'
 
 	if params.len > 0 {
@@ -46,7 +38,27 @@ fn (c &Client) send_request_with_body<T>(method Method, url string, params map[s
 	req.add_custom_header('X-Api-Key', c.api_key) ?
 
 	res := req.do() ?
-	data := json.decode(Response<T>, res.text) ?
+
+	return res
+}
+
+// send_request<T> just calls send_request_with_body<T> with an empty body.
+fn (c &Client) send_request<T>(method Method, url string, params map[string]string) ?Response<T> {
+	return c.send_request_with_body<T>(method, url, params, '')
+}
+
+// send_request_with_body<T> is a convenience method for sending requests to
+// the repos API. It mostly does string manipulation to create a query string
+// containing the provided params.
+fn (c &Client) send_request_with_body<T>(method Method, url string, params map[string]string, body string) ?Response<T> {
+	res_text := c.send_request_raw_response(method, url, params, body) ?
+	data := json.decode(Response<T>, res_text) ?
 
 	return data
 }
+
+fn (c &Client) send_request_raw_response(method Method, url string, params map[string]string, body string) ?string {
+	res := c.send_request_raw(method, url, params, body) ?
+
+	return res.text
+}
diff --git a/src/client/logs.v b/src/client/logs.v
index 9182f69..19575a6 100644
--- a/src/client/logs.v
+++ b/src/client/logs.v
@@ -27,6 +27,12 @@ pub fn (c &Client) get_build_log(id int) ?Response<BuildLog> {
 	return data
 }
 
+pub fn (c &Client) get_build_log_content(id int) ?string {
+	data := c.send_request_raw_response(Method.get, '/api/logs/$id/content', {}, '') ?
+
+	return data
+}
+
 pub fn (c &Client) add_build_log(repo_id int, start_time time.Time, end_time time.Time, arch string, exit_code int, content string) ?Response<string> {
 	params := {
 		'repo':      repo_id.str()
diff --git a/src/console/console.v b/src/console/console.v
new file mode 100644
index 0000000..6f296bd
--- /dev/null
+++ b/src/console/console.v
@@ -0,0 +1 @@
+module console
diff --git a/src/git/cli.v b/src/console/git/git.v
similarity index 100%
rename from src/git/cli.v
rename to src/console/git/git.v
diff --git a/src/console/logs/logs.v b/src/console/logs/logs.v
new file mode 100644
index 0000000..14aeddf
--- /dev/null
+++ b/src/console/logs/logs.v
@@ -0,0 +1,99 @@
+module logs
+
+import cli
+import env
+import client
+import db
+
+struct Config {
+	address string [required]
+	api_key string [required]
+}
+
+pub fn cmd() cli.Command {
+	return cli.Command{
+		name: 'logs'
+		description: 'Interact with the build logs API.'
+		commands: [
+			cli.Command{
+				name: 'list'
+				description: 'List the build logs. If a repo ID is provided, only list the build logs for that repo.'
+				flags: [
+					cli.Flag{
+						name: 'repo'
+						description: 'ID of the Git repo to restrict list to.'
+						flag: cli.FlagType.int
+					},
+				]
+				execute: fn (cmd cli.Command) ? {
+					config_file := cmd.flags.get_string('config-file') ?
+					conf := env.load<Config>(config_file) ?
+
+					repo_id := cmd.flags.get_int('repo') ?
+
+					if repo_id == 0 { list(conf) ? } else { list_for_repo(conf, repo_id) ? }
+				}
+			},
+			cli.Command{
+				name: 'info'
+				required_args: 1
+				usage: 'id'
+				description: 'Show all info for a specific build log.'
+				execute: fn (cmd cli.Command) ? {
+					config_file := cmd.flags.get_string('config-file') ?
+					conf := env.load<Config>(config_file) ?
+
+					id := cmd.args[0].int()
+					info(conf, id) ?
+				}
+			},
+			cli.Command{
+				name: 'content'
+				required_args: 1
+				usage: 'id'
+				description: 'Output the content of a build log to stdout.'
+				execute: fn (cmd cli.Command) ? {
+					config_file := cmd.flags.get_string('config-file') ?
+					conf := env.load<Config>(config_file) ?
+
+					id := cmd.args[0].int()
+					content(conf, id) ?
+				}
+			},
+		]
+	}
+}
+
+fn print_log_list(logs []db.BuildLog) {
+	for log in logs {
+		println('$log.id\t$log.start_time\t$log.exit_code')
+	}
+}
+
+fn list(conf Config) ? {
+	c := client.new(conf.address, conf.api_key)
+	logs := c.get_build_logs() ?.data
+
+	print_log_list(logs)
+}
+
+fn list_for_repo(conf Config, repo_id int) ? {
+	c := client.new(conf.address, conf.api_key)
+	logs := c.get_build_logs_for_repo(repo_id) ?.data
+
+	print_log_list(logs)
+}
+
+fn info(conf Config, id int) ? {
+	c := client.new(conf.address, conf.api_key)
+	log := c.get_build_log(id) ?.data
+
+	print(log)
+}
+
+fn content(conf Config, id int) ? {
+	c := client.new(conf.address, conf.api_key)
+	content := c.get_build_log_content(id) ?
+
+	println(content)
+}
diff --git a/src/db/logs.v b/src/db/logs.v
index 9ce2865..05973af 100644
--- a/src/db/logs.v
+++ b/src/db/logs.v
@@ -12,6 +12,20 @@ pub:
 	exit_code  int       [nonull]
 }
 
+pub fn (bl &BuildLog) str() string {
+	mut parts := [
+		'id: $bl.id',
+		'repo id: $bl.repo_id',
+		'start time: $bl.start_time',
+		'end time: $bl.end_time',
+		'arch: $bl.arch',
+		'exit code: $bl.exit_code',
+	]
+	str := parts.join('\n')
+
+	return str
+}
+
 // get_build_logs returns all BuildLog's in the database.
 pub fn (db &VieterDb) get_build_logs() []BuildLog {
 	res := sql db.conn {
diff --git a/src/main.v b/src/main.v
index 4ba6d30..41d0d33 100644
--- a/src/main.v
+++ b/src/main.v
@@ -4,7 +4,8 @@ import os
 import server
 import cli
 import build
-import git
+import console.git
+import console.logs
 import cron
 
 fn main() {
@@ -27,6 +28,7 @@ fn main() {
 			build.cmd(),
 			git.cmd(),
 			cron.cmd(),
+			logs.cmd(),
 		]
 	}
 
-- 
2.40.1


From 5f7d7c47801b3b6145e945c9a69c3d891085f593 Mon Sep 17 00:00:00 2001
From: Jef Roosens <roosensjef@gmail.com>
Date: Sat, 7 May 2022 22:06:17 +0200
Subject: [PATCH 09/10] doc: added documentation to all functions

---
 src/client/client.v     |  9 ++++++---
 src/client/git.v        | 10 +++++-----
 src/client/logs.v       |  5 +++++
 src/console/logs/logs.v |  7 +++++++
 src/db/git.v            |  2 ++
 src/db/logs.v           |  1 +
 src/server/logs.v       |  7 ++++++-
 7 files changed, 32 insertions(+), 9 deletions(-)

diff --git a/src/client/client.v b/src/client/client.v
index 12c92d3..25224a5 100644
--- a/src/client/client.v
+++ b/src/client/client.v
@@ -11,6 +11,7 @@ pub:
 	api_key string
 }
 
+// new creates a new Client instance.
 pub fn new(address string, api_key string) Client {
 	return Client{
 		address: address
@@ -18,6 +19,8 @@ pub fn new(address string, api_key string) Client {
 	}
 }
 
+// send_request_raw sends an HTTP request, returning the http.Response object.
+// It encodes the params so that they're safe to pass as HTTP query parameters.
 fn (c &Client) send_request_raw(method Method, url string, params map[string]string, body string) ?http.Response {
 	mut full_url := '$c.address$url'
 
@@ -47,9 +50,8 @@ fn (c &Client) send_request<T>(method Method, url string, params map[string]stri
 	return c.send_request_with_body<T>(method, url, params, '')
 }
 
-// send_request_with_body<T> is a convenience method for sending requests to
-// the repos API. It mostly does string manipulation to create a query string
-// containing the provided params.
+// send_request_with_body<T> calls send_request_raw_response & parses its
+// output as a Response<T> object.
 fn (c &Client) send_request_with_body<T>(method Method, url string, params map[string]string, body string) ?Response<T> {
 	res_text := c.send_request_raw_response(method, url, params, body) ?
 	data := json.decode(Response<T>, res_text) ?
@@ -57,6 +59,7 @@ fn (c &Client) send_request_with_body<T>(method Method, url string, params map[s
 	return data
 }
 
+// send_request_raw_response returns the raw text response for an HTTP request.
 fn (c &Client) send_request_raw_response(method Method, url string, params map[string]string, body string) ?string {
 	res := c.send_request_raw(method, url, params, body) ?
 
diff --git a/src/client/git.v b/src/client/git.v
index 7f4c27a..b09d4c2 100644
--- a/src/client/git.v
+++ b/src/client/git.v
@@ -4,21 +4,21 @@ import db { GitRepo }
 import net.http { Method }
 import response { Response }
 
-// get_repos returns the current list of repos.
+// get_git_repos returns the current list of repos.
 pub fn (c &Client) get_git_repos() ?[]GitRepo {
 	data := c.send_request<[]GitRepo>(Method.get, '/api/repos', {}) ?
 
 	return data.data
 }
 
-// get_repo returns the repo for a specific ID.
+// get_git_repo returns the repo for a specific ID.
 pub fn (c &Client) get_git_repo(id int) ?GitRepo {
 	data := c.send_request<GitRepo>(Method.get, '/api/repos/$id', {}) ?
 
 	return data.data
 }
 
-// add_repo adds a new repo to the server.
+// add_git_repo adds a new repo to the server.
 pub fn (c &Client) add_git_repo(url string, branch string, repo string, arch []string) ?Response<string> {
 	mut params := {
 		'url':    url
@@ -35,14 +35,14 @@ pub fn (c &Client) add_git_repo(url string, branch string, repo string, arch []s
 	return data
 }
 
-// remove_repo removes the repo with the given ID from the server.
+// remove_git_repo removes the repo with the given ID from the server.
 pub fn (c &Client) remove_git_repo(id int) ?Response<string> {
 	data := c.send_request<string>(Method.delete, '/api/repos/$id', {}) ?
 
 	return data
 }
 
-// patch_repo sends a PATCH request to the given repo with the params as
+// patch_git_repo sends a PATCH request to the given repo with the params as
 // payload.
 pub fn (c &Client) patch_git_repo(id int, params map[string]string) ?Response<string> {
 	data := c.send_request<string>(Method.patch, '/api/repos/$id', params) ?
diff --git a/src/client/logs.v b/src/client/logs.v
index 19575a6..8c53213 100644
--- a/src/client/logs.v
+++ b/src/client/logs.v
@@ -5,12 +5,14 @@ import net.http { Method }
 import response { Response }
 import time
 
+// get_build_logs returns all build logs.
 pub fn (c &Client) get_build_logs() ?Response<[]BuildLog> {
 	data := c.send_request<[]BuildLog>(Method.get, '/api/logs', {}) ?
 
 	return data
 }
 
+// get_build_logs_for_repo returns all build logs for a given repo.
 pub fn (c &Client) get_build_logs_for_repo(repo_id int) ?Response<[]BuildLog> {
 	params := {
 		'repo': repo_id.str()
@@ -21,18 +23,21 @@ pub fn (c &Client) get_build_logs_for_repo(repo_id int) ?Response<[]BuildLog> {
 	return data
 }
 
+// get_build_log returns a specific build log.
 pub fn (c &Client) get_build_log(id int) ?Response<BuildLog> {
 	data := c.send_request<BuildLog>(Method.get, '/api/logs/$id', {}) ?
 
 	return data
 }
 
+// get_build_log_content returns the contents of the build log file.
 pub fn (c &Client) get_build_log_content(id int) ?string {
 	data := c.send_request_raw_response(Method.get, '/api/logs/$id/content', {}, '') ?
 
 	return data
 }
 
+// add_build_log adds a new build log to the server.
 pub fn (c &Client) add_build_log(repo_id int, start_time time.Time, end_time time.Time, arch string, exit_code int, content string) ?Response<string> {
 	params := {
 		'repo':      repo_id.str()
diff --git a/src/console/logs/logs.v b/src/console/logs/logs.v
index 14aeddf..e3c7d14 100644
--- a/src/console/logs/logs.v
+++ b/src/console/logs/logs.v
@@ -10,6 +10,7 @@ struct Config {
 	api_key string [required]
 }
 
+// cmd returns the cli module that handles the build repos API.
 pub fn cmd() cli.Command {
 	return cli.Command{
 		name: 'logs'
@@ -64,12 +65,14 @@ pub fn cmd() cli.Command {
 	}
 }
 
+// print_log_list prints a list of logs.
 fn print_log_list(logs []db.BuildLog) {
 	for log in logs {
 		println('$log.id\t$log.start_time\t$log.exit_code')
 	}
 }
 
+// list prints a list of all build logs.
 fn list(conf Config) ? {
 	c := client.new(conf.address, conf.api_key)
 	logs := c.get_build_logs() ?.data
@@ -77,6 +80,7 @@ fn list(conf Config) ? {
 	print_log_list(logs)
 }
 
+// list prints a list of all build logs for a given repo.
 fn list_for_repo(conf Config, repo_id int) ? {
 	c := client.new(conf.address, conf.api_key)
 	logs := c.get_build_logs_for_repo(repo_id) ?.data
@@ -84,6 +88,7 @@ fn list_for_repo(conf Config, repo_id int) ? {
 	print_log_list(logs)
 }
 
+// info print the detailed info for a given build log.
 fn info(conf Config, id int) ? {
 	c := client.new(conf.address, conf.api_key)
 	log := c.get_build_log(id) ?.data
@@ -91,6 +96,8 @@ fn info(conf Config, id int) ? {
 	print(log)
 }
 
+// content outputs the contents of the log file for a given build log to
+// stdout.
 fn content(conf Config, id int) ? {
 	c := client.new(conf.address, conf.api_key)
 	content := c.get_build_log_content(id) ?
diff --git a/src/db/git.v b/src/db/git.v
index 7aba284..9a475a5 100644
--- a/src/db/git.v
+++ b/src/db/git.v
@@ -153,6 +153,8 @@ pub fn (db &VieterDb) update_git_repo_archs(repo_id int, archs []GitRepoArch) {
 	}
 }
 
+// git_repo_exists is a utility function that checks whether a repo with the
+// given id exists.
 pub fn (db &VieterDb) git_repo_exists(repo_id int) bool {
 	db.get_git_repo(repo_id) or { return false }
 
diff --git a/src/db/logs.v b/src/db/logs.v
index 05973af..817db78 100644
--- a/src/db/logs.v
+++ b/src/db/logs.v
@@ -12,6 +12,7 @@ pub:
 	exit_code  int       [nonull]
 }
 
+// str returns a string representation.
 pub fn (bl &BuildLog) str() string {
 	mut parts := [
 		'id: $bl.id',
diff --git a/src/server/logs.v b/src/server/logs.v
index f53464d..b048dc4 100644
--- a/src/server/logs.v
+++ b/src/server/logs.v
@@ -9,6 +9,8 @@ import time
 import os
 import util
 
+// get_logs returns all build logs in the database. A 'repo' query param can
+// optionally be added to limit the list of build logs to that repository.
 ['/api/logs'; get]
 fn (mut app App) get_logs() web.Result {
 	if !app.is_authorized() {
@@ -24,6 +26,7 @@ fn (mut app App) get_logs() web.Result {
 	return app.json(http.Status.ok, new_data_response(logs))
 }
 
+// get_single_log returns the build log with the given id.
 ['/api/logs/:id'; get]
 fn (mut app App) get_single_log(id int) web.Result {
 	if !app.is_authorized() {
@@ -35,8 +38,9 @@ fn (mut app App) get_single_log(id int) web.Result {
 	return app.json(http.Status.ok, new_data_response(log))
 }
 
+// get_log_content returns the actual build log file for the given id.
 ['/api/logs/:id/content'; get]
-fn (mut app App) get_log_contents(id int) web.Result {
+fn (mut app App) get_log_content(id int) web.Result {
 	if !app.is_authorized() {
 		return app.json(http.Status.unauthorized, new_response('Unauthorized.'))
 	}
@@ -58,6 +62,7 @@ fn parse_query_time(query string) ?time.Time {
 	return t
 }
 
+// post_log adds a new log to the database.
 ['/api/logs'; post]
 fn (mut app App) post_log() web.Result {
 	if !app.is_authorized() {
-- 
2.40.1


From 30cce4fa72c4eaf632dc7a329392f1dd05edd326 Mon Sep 17 00:00:00 2001
From: Jef Roosens <roosensjef@gmail.com>
Date: Sat, 7 May 2022 22:13:35 +0200
Subject: [PATCH 10/10] chore: updated changelog

---
 CHANGELOG.md | 7 +++++++
 1 file changed, 7 insertions(+)

diff --git a/CHANGELOG.md b/CHANGELOG.md
index 2bbe4f0..7d9eb4d 100644
--- a/CHANGELOG.md
+++ b/CHANGELOG.md
@@ -5,6 +5,13 @@ All notable changes to this project will be documented in this file.
 The format is based on [Keep a Changelog](https://keepachangelog.com/en/1.0.0/),
 and this project adheres to [Semantic Versioning](https://semver.org/spec/v2.0.0.html).
 
+## [Unreleased](https://git.rustybever.be/vieter/vieter/src/branch/dev)
+
+### Added
+
+* Web API for adding & querying build logs
+* CLI commands to access build logs API
+
 ## [0.3.0-alpha.1](https://git.rustybever.be/vieter/vieter/src/tag/0.3.0-alpha.1)
 
 ### Changed
-- 
2.40.1