jjr-newsflash/PKGBUILD

# vim: ft=bash
# Maintainer: Jef Roosens
# Contributor: Felix Bühler <account at buehler dot rocks>

_pkgname='news_flash_gtk'
pkgname='jjr-newsflash-git'
pkgver=1141.40ff7cf
pkgrel=1
pkgdesc='The spiritual successor to FeedReader (development version)'
arch=('x86_64')

url='https://gitlab.com/news-flash/news_flash_gtk'
license=('GPL3')
depends=(
    'libadwaita'
    'gtk4'
    'webkit2gtk-5.0'
)
makedepends=(
    'git'
    'meson'
    'rust'
)

conflicts=('newsflash' 'newsflash-git')
source=("${_pkgname}::git+https://gitlab.com/news-flash/news_flash_gtk.git")
md5sums=("SKIP")

pkgver() {
	cd "${_pkgname}"

	echo $(git rev-list --count HEAD).$(git rev-parse --short HEAD)
}

prepare() {
    cd "${_pkgname}"

    # Trustdns likes to bug out when not on a stable network
    sed -i 's/\.trust_dns(true)/\.trust_dns(false)/' src/util/mod.rs
}

build() {
	cd "${_pkgname}"

	arch-meson _build
	ninja -C _build
}

package() {
	cd "${_pkgname}"

	env DESTDIR="${pkgdir}" ninja -C _build install
}